home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr11
/
powerb5.zip
/
P5SPR003.TIP
< prev
next >
Wrap
Text File
|
1993-06-01
|
5KB
|
111 lines
Loans with variable interest rates can present problems if
you're trying to create a table of payments in a
spreadsheet. Many books show how to calculate payments for
fixed-rate loans using 1-2-3's @PMT() function, but I looked
through more than a dozen books on spreadsheets and basic
accounting, and I couldn't find one technique for
calculating variable-rate payments. So I developed my own.
The @PMT() function found in most spreadsheets takes the
form @PMT(principal, interest, term), where principal is the
amount of the loan, interest is the interest rate per period
(usually per month or year), and term is the number of
payment periods. But @PMT() doesn't take variable interest
rates into account; it assumes that the payments remain
constant. My solution is to use @PMT() to calculate
different payments each month. This is the equivalent of
assuming that the loan starts over again each month, with
one less month in the term.
Here's a sample spreadsheet for a six-month loan [FIGURE 1].
The first two rows include general information about the
loan. Starting in row 6, column A lists each payment's due
date, column B the number of payments remaining, and column
C the interest rate. Columns D through G use assorted
formulas to calculate each month's total payment, the
interest and principal portions of that payment, and the
remaining principal balance.
A B C D E F G
1 Term of loan: 6 months Amount of loan 10,000.00
2 Date of loan: 09-Sep-91
3
4 Payment Pmts Interest Monthly Paid as Paid as Balance
5 due on left rate payment interest principal remaining
6 09-Oct-91 6 10.00% 1,715.61 83.33 1,632.28 8,367.72
7 09-Nov-91 5 10.00% 1,715.61 69.73 1,645.88 6,721.84
8 09-Dec-91 4 10.00% 1,715.61 56.02 1,659.60 5,062.24
9 09-Jan-92 3 17.00% 1,735.45 71.72 1,663.73 3,398.51
10 09-Feb-92 2 17.00% 1,735.45 48.15 1,687.30 1,711.21
11 09-Mar-92 1 17.00% 1,735.45 24.24 1,711.21 0.00
This amortization table for a variable-rate loan was created
using the @PMT function. The trick: the formula is applied
as if the loan starts over each month.
If you create this table yourself, be sure to fill in the
correct formulas [See table, below]. With the exception of
the interest rate, rows 8 through 11 of the worksheet
contain the same formulas as row 7; once you have written
the first seven rows, use /Copy to copy A7..G7 to A8..G11.
The key to this worksheet is the series of @PMT() formulas
in column D. Each one reads a different balance and a
different interest rate, producing dynamic (and possibly
depressing) monthly payments.
C2: @DATEVALUE("3/9/92")
A6: +C2+@CHOOSE(@MONTH(C2)-1,31,@IF(@MOD(@YEAR(C2),4)=0,29,28),31,30,31,30,31,31,30,31,30,31)
D6: @PMT(G1,C6/12,B6)
E6: +C6/12*G1
F6: +D6-E6
G6: +G1-F6
A7: +A6+@CHOOSE(@MONTH(A6)-1,31,@IF(@MOD(@YEAR(A6),4)=0,29,28),31,30,31,30,31,31,30,31,30,31)
B7: +B6-1
C7: +C6
D7: @PMT(G6,C7/12,B7)
E7: +C7/12*G6
F7: +D7-E7
G7: @ROUND(G6-F7,2)
These formulas were used to create the spreadsheet above.
Rows 8 through 11 are created by copying row 7, then
changing the interest rates as required.
As long as the interest rates remain the same, so do the
payments. But change the interest rate for any one month, as
we did for July (the previously mentioned exception to rows
8 through 11 being identical to row 7), and everything
changes from that month on. Column A shows a useful formula
for listing dates that always land on the same day of the
month. Basically, each formula adds 28, 29, 30, or 31 days
to the date in another cell, usually the one above it. You
may find it necessary to add @ROUND() functions to certain
formulas. This is especially true where a formula might
return 0.00. 1-2-3 may return a confusing -0.00 or 0.01; in
a 30-year mortgage or a large loan, the odd penny difference
can usually be ignored.
Before committing funds or signing a legal document, check
with your bank or financial institution to see how they
figure their variable-rate loans. Their figures and yours
will probably differ slightly. One reason: Your bank will
adjust your repayment schedule if you choose to make the
first payment at a time other than exactly one month after
the loan date.
James Kennedy,
St. Augustine, Florida
Editor's Note: You don't have to enter the sample
spreadsheet to try it out, because we've done it for you.
Look for the file P5SPR\INTEREST.WK1 on your PowerBase *.*
disk.
Title: Waxing and Waning Interest
Category: SPR
Issue Date: April, 1992
Editor: Brett Glass
Supplementary Files: P5SPR\INTEREST.WK1
Filename: P5SPR003.TIP